# ---------------------------------------------------------------------------------------------------------- #
# Use this with GeoMob http://www.metaltheater.com/GeoMob/ ------------------------------------------------- #
# Export cachedata to a file called c:\temp\caches.txt ----------------------------------------------------- #
# Created by ninasger -------------------------------------------------------------------------------------- #
# If you want the caches.txt file to be created in another path, change the path in the end of this macro -- #
# ---------------------------------------------------------------------------------------------------------- #

$out=""
$name=""
$ThisRecord = 0
$x = 0
$_Symbol=""
$CleanDescription=""


Goto Position=Top
While .not. $_eol

# Give some information about processing
  $ThisRecord = $ThisRecord + 1
  $x = $x + 1
  if $x = 5
    $status = "Now processing: " + "$ThisRecord" + " of " + "$_Count"
    ShowStatus msg="$status"  
    $x = 0
  endif
  
  If $d_CacheType = "B"
	$_Symbol = "Letterbox"
  EndIf
  
  If $d_CacheType = "C"
	$_Symbol = "CITO"
  EndIf
  
  If $d_CacheType = "E"
	$_Symbol = "Event"
  EndIf
  
  If $d_CacheType = "M"
	$_Symbol = "Multi"
  EndIf
  
  If $d_CacheType = "R"
	$_Symbol = "Earth"
  EndIf
  
  If $d_CacheType = "T"
	$_Symbol = "Traditional"
  EndIf
  
  If $d_CacheType = "U"
	$_Symbol = "Mystery"
  EndIf
  
  If $d_CacheType = "V"
	$_Symbol = "Virtual"
  EndIf
  
  If $d_CacheType = "W"
	$_Symbol = "Webcam"
  EndIf
  
  $data = $d_latitude + " " + $d_longitude 
  $utm = GCalc($data,"FormatMinutes")
  $utm = Replace(";"," ",$utm,true)
  
  $CleanDescription = RegExReplace("</?[a-z][a-z0-9]*[^<>]*>", $d_LongDescription, "")

  $out = $out + "===" + $_NewLine
  $out = $out + $d_Name + $_NewLine
  $out = $out + "by " + $d_OwnerName + $_NewLine + $_NewLine
  $out = $out + $utm + $_NewLine
  $out = $out + "Difficulty: " + NumToStr($d_Difficulty) + " out of 5  "
  $out = $out + "Terrain: " + NumToStr($d_Terrain) + " out of 5" + $_NewLine + $_NewLine
  $out = $out + "Cachetype: " + $_Symbol + $_NewLine
  $out = $out + "Cachesize: " + $d_Container + $_NewLine
  $out = $out + $CleanDescription + $_NewLine + $_NewLine
  $out = $out + "Hint " + $d_Hints + $_NewLine + $_NewLine

  Goto Position=Next
  
EndWhile

# Write file to temp-directory
$FileName = "c:\temp\caches.txt"
$Error = PutFile($FileName,$out)

Goto Position=Top